GraffitiSuite Documentation

GraffitiWebTreeItem

GraffitiWebTree provides a constructor for creating items that have a FontAwesome icon to the left of the node's text.

dim firstItemFirstChild as new GraffitiWebTreeItem( "test child", "fas fa-times" )
firstItemFirstChild.Checkbox = True
me.AddItem( firstItemFirstChild, firstItem )

As GraffitiWebTree items are maintained in a relational manner (using Parents and Children), iterating items can be a tough concept to grasp. The easiest path is to create a method to do your multi-level iteration and perform a specific function. For instance, the following code will loop through all items in the tree and give you an opportunity to do something with the individual item's CheckValue property:

Private Sub StoreCheckValues(ofTree as GraffitiWebTree, inNode as GraffitiWebTreeItem = Nil)
  dim arrCheck() as GraffitiWebTreeItem
  if not IsNull( inNode ) Then
    arrCheck = inNode.Children
  else
    arrCheck = ofTree.Items
  end if
 
  dim intCycle as Integer
  dim intMax as Integer = arrCheck.Ubound
 
  '// Note that you will want to perform the same operation on the parent
  '   before the loop if you're providing inNode and want its value recorded.
 
  dim currentItem as GraffitiWebTreeItem
  for intCycle = 0 to intMax
    currentItem = arrCheck(intCycle)
 
    if currentItem.Checkbox then '// Has a checkbox
      '// Store the value of CheckValue
    end if
 
    '// The following line will iterate over the children of currentItem.
    '   If you only want to do top-level children then you can comment this
    '   or add a method parameter and check it here.
    if currentItem.Children.Ubound >= 0 then StoreCheckValues( ofTree, currentItem )
  next
End Sub

Then you would simply call the method and pass in your tree to iterate through all items:

StoreCheckValues(myTreeInstance)

Or, if you only want to iterate over a specific branch of the tree:

StoreCheckValues(myTreeInstance, myBranchTreeItem)